henrov/nixos

Fork 0

Files

T

henrov 6d9d4b6bcc Regenerated

2026-04-17 19:51:01 +02:00

135 KiB

Raw Blame History

Droidnix: A Dendritic NixOS + Home Manager Configuration NixOS Configuration Structure

Shortcuts
Introduction
- What is Droidnix
  - Installed components:
    - Core
    - Hyprland
  - Goals, project Structure, import hierarchy
Root Level
Generated Structure
- First Setup
The Assets Folder
- generated/assets/2_b_installed.conf
- generated/assets/aliases.conf
The Actual Code
generated/traveldroid/modules/apps
generated/modules/traveldroid/desktop
generated/modules/traveldroid/system
generated/users
- generated/users/
These are all the prepared config files

Shortcuts

Introduction The Assets Folder The Actual Code en configs

—

Introduction intro

What is Droidnix

Droidnix is a modular, declarative NixOS + Home Manager configuration system. with configurations managed via Emacs Org and Nix Flakes. The project is designed for reproducibility, maintainability, and cross-machine compatibility.

Installed components:

Core

Hyprland

Goals, project Structure, import hierarchy

This project uses a modular NixOS configuration with Hyprland support, designed for literate programming and cross-device reusability. The Droidnix repository is organized into two main parts:

.assets/: Static, non-generated files (e.g., configs, scripts, themes).
Generated files and folders

Root Level

flake.nix is the entry point and imports:
- generated/assets/
- generated/<host>/modules/
- generated/hosts/

Generated Structure

The generated/ directory contains all generated configurations, divided into three main groups: system, hyprland, and mangowc.

First Setup

Clone this repository.
Run the setup script: ./setup_droid.
Tangle this Org file to generate Nix configurations: C-c C-v t in Emacs or use this: emacs README.org --batch -f org-babel-tangle && emacs --batch --eval "(setq org-html-htmlize-output-type nil)" README.org -f org-html-export-to-html
Build and switch: sudo nixos-rebuild switch --flake .#<hostname>.

—

The Assets Folder assets

The .assets/ folder contains all static files, such as configs, scripts, and themes. These files are not generated and can be edited directly.

`generated/assets/2_b_installed.conf`

This is a list of additional apps to install

#packages
_1password-gui
audacity
baobab
bat
blender
brave
btop
chromium
cliphist
collabora-online
comma
direnv
duf
delta
eza
fd
file
fzf
gimp
git
gparted
grim
handbrake
hyperfine
just
jq
kdePackages.kdeconnect-kde
libreoffice
lua
nextcloud-client
nextcloud-talk-desktop
nix-index
nix-output-monitor
nh
obsidian
openssl
pandoc
postman
python3
qdirstat
ripgrep
signal-desktop
slurp
spotify
solaar
swappy
sweethome3d.application
tea
todoist
tree
usbutils
vlc
wev
wget
wl-clipboard
wf-recorder
yazi
z-lua
zed-editor
zoxide

#flatpaks
eu.betterbird.Betterbird
com.todoist.Todoist

`generated/assets/aliases.conf`

This is a list of additional apps to install

#File & navigation
repo=cd ~/Repos && ls -lah

#Nix commands
nps=xdg-open https://search.nixos.org

#system commands
please=sudo
pls=sudo
rb=sudo reboot
po=sudo poweroff

#flatpak commands
fpl=flatpak list
fps=flatpak search
fpi=flatpak install
fpr=flatpak run
fpu=flatpak update

#ssh commands
nxc=ssh henrov@nextcloud.data-pro.nu

#app shortcuts
vs=code
keys=hyprctl binds

The Actual Code code

This section contains the Org blocks for tangling Nix code into the generated folders.

`generated/flake.nix`

The Nix flake definition for Droidnix.

{
  description = "Droidnix: A dendritic NixOS + Home Manager configuration";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";

    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    quickshell = {
        url = "git+https://git.outfoxxed.me/outfoxxed/quickshell";
        inputs.nixpkgs.follows = "nixpkgs";
      };

    import-tree.url = "github:vic/import-tree";

    stylix = {
      url = "github:nix-community/stylix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    flatpak = {
      url = "github:gmodena/nix-flatpak";
    };

    emacs-overlay = {
      url = "github:nix-community/emacs-overlay";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    zen-browser = {
      url = "github:youwen5/zen-browser-flake";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    hyprland.url = "github:hyprwm/Hyprland";
  };

  outputs = { self, nixpkgs, home-manager, import-tree, stylix, hyprland, emacs-overlay, zen-browser, flatpak, ... }:
    let
      system = "x86_64-linux";
      flakeRoot = self;
    in {
      nixosConfigurations = {
        traveldroid = nixpkgs.lib.nixosSystem {
          inherit system;

          modules = [
            ({ ... }: {
              nixpkgs.overlays = [ emacs-overlay.overlays.default ];
            })
            flatpak.nixosModules."nix-flatpak"
            ./generated/hosts/traveldroid/host.nix
            ./generated/users/henrov.nix
          ];
          specialArgs = {
            inherit flakeRoot;
            inherit home-manager import-tree stylix hyprland zen-browser;
          };
        };
      };
    };
}

`generated/modules/traveldroid/system/colors.nix`

Setting the colors for Droidnix.

{ lib, config, pkgs, flakeRoot, ... }:
let
  colors = {
    crust     = "#11111b";
    mantle    = "#181825";
    base      = "#1e1e2e";
    surface0  = "#313244";
    surface1  = "#45475a";
    surface2  = "#585b70";
    overlay0  = "#6c7086";
    overlay1  = "#7f849c";
    overlay2  = "#9399b2";
    subtext0  = "#a6adc8";
    subtext1  = "#bac2de";
    text      = "#cdd6f4";
    rosewater = "#f5e0dc";
    flamingo  = "#f2cdcd";
    pink      = "#f5c2e7";
    mauve     = "#cba6f7";
    red       = "#f38ba8";
    maroon    = "#eba0ac";
    peach     = "#fab387";
    yellow    = "#f9e2af";
    green     = "#a6e3a1";
    teal      = "#94e2d5";
    sapphire  = "#74c7ec";
    blue      = "#89b4fa";
    lavender  = "#b4befe";
  };

  username = config.defaultUser or "henrov";

  cssContent = ''
    /* Catppuccin Mocha Palette - auto-generated, do not edit manually */
  '' + lib.concatStringsSep "\n" (
    lib.mapAttrsToList (name: value:
      "@define-color ${name} ${value};"
    ) colors
  ) + "\n@define-color base-alpha rgba(30, 30, 46, 0.9);";

  qmlContent = ''
    pragma Singleton
    // Catppuccin Mocha Palette - auto-generated, do not edit manually
    import QtQuick
    QtObject {
        readonly property color baseAlpha: Qt.rgba(30/255, 30/255, 46/255, 0.9)
  '' + lib.concatStringsSep "\n" (
    lib.mapAttrsToList (name: value:
      "    readonly property color ${name}: \"${value}\""
    ) colors
  ) + "\n}";

in
{
  home-manager.users.${username} = {
    home.file = {
      ".config/shared/Colors.css" = {
        text = cssContent;
        force = true;
      };
      ".config/quickshell/Colors.qml" = {
        text = qmlContent;
        force = true;
      };
      ".config/quickshell/powermenu/Colors.qml" = {
        text = qmlContent;
        force = true;
      };
      ".config/quickshell/powermenu/qmldir" = {
        text = "singleton Colors 1.0 Colors.qml";
        force = true;
      };
    };
  };
}

`generated/hosts/traveldroid/boot.nix`

# --- This file has been auto-generated. For permanent changes alter the appropriate block in the README.org. ---
{ config, pkgs, lib, flakeRoot, ... }:
{
  boot.loader = {
    systemd-boot.enable = true;
    efi.canTouchEfiVariables = true;
    efi.efiSysMountPoint = "/boot";
    timeout = 5;
  };
  boot.kernelPackages = pkgs.linuxPackages_latest;
  boot.kernelParams = [
    "quiet"
    "splash"
    "udev.log_level=3"
    "rd.systemd.show_status=false"
    # Sleep / power management
    "mem_sleep_default=deep"       # Use S3 deep sleep, fixes sleep not working
    "acpi_osi=Linux"               # Tell ACPI this is a Linux system
    "acpi_backlight=native"        # Proper backlight control
    # Intel GPU — fixes screen blinking on sleep/wake
    "i915.enable_psr=0"
    "i915.enable_psr2_sel_fetch=0"
    # Prevent nvme from waking the system
    "nvme.noacpi=1"
  ];
  boot.consoleLogLevel = 0;
  #boot.initrd.systemd.enable = true;
  boot.initrd.availableKernelModules = [
    "xhci_pci"
    "nvme"
    "usb_storage"
    "sd_mod"
    "rtsx_usb_sdmmc"
  ];
  hardware.enableAllFirmware = true;
  boot.kernelModules = [
    "kvm-intel"
    "asus_wmi"    # Asus-specific power/fan/keyboard control
  ];
  boot.plymouth = {
    enable = true;
  };
  hardware.cpu.intel.updateMicrocode = lib.mkDefault config.hardware.enableRedistributableFirmware;
  nixpkgs.hostPlatform = lib.mkDefault "x86_64-linux";

  # Power management
  powerManagement.enable = true;
  services.logind.settings.Login = {
    HandleSleepKey = "ignore";
    HandleSleepKeyLongPress = "ignore";
  };
  services.thermald.enable = true;   # Intel thermal management daemon
  services.tlp = {
    enable = true;
    settings = {
      CPU_SCALING_GOVERNOR_ON_AC  = "performance";
      CPU_SCALING_GOVERNOR_ON_BAT = "powersave";
      CPU_ENERGY_PERF_POLICY_ON_BAT = "power";
      PLATFORM_PROFILE_ON_AC  = "performance";
      PLATFORM_PROFILE_ON_BAT = "low-power";
    };
  };
}

`generated/hosts/traveldroid/hardware-configuration.nix`

Boot into NixOS Live ISO or your installed system.
Open a terminal.
Run: <code>sudo nixos-generate-config –root /mnt</code> (Omit –root /mnt if already running NixOS.)

{
  hostname,
  pkgs,
  lib,
  modulesPath,
  user,
  config,
  ...
}:
{
  imports = [
    # (modulesPath + "/installer/scan/not-detected.nix")
    #../../hardware/hardware.nix
  ];

  boot.initrd.availableKernelModules = [
    "xhci_pci"
    "nvme"
    "usb_storage"
    "sd_mod"
    "rtsx_usb_sdmmc"
  ];
  boot.initrd.kernelModules = [ ];
  boot.kernelModules = [ "kvm-intel" ];
  boot.extraModulePackages = [ ];

  fileSystems."/" = {
    device = "/dev/disk/by-uuid/69433a14-fbaf-401b-af85-cd1bbf02b4e2";
    fsType = "ext4";
  };

  fileSystems."/boot" = {
    device = "/dev/disk/by-uuid/811D-0676";
    fsType = "vfat";
    options = [
      "fmask=0077"
      "dmask=0077"
    ];
  };

  swapDevices = [
    { device = "/dev/disk/by-uuid/b6c557c2-7682-460b-a5e7-8f6f2f429a3a"; }
  ];

  nixpkgs.hostPlatform = lib.mkDefault "x86_64-linux";
  hardware.cpu.intel.updateMicrocode = lib.mkDefault config.hardware.enableRedistributableFirmware;
}

`generated/hosts/traveldroid/host.nix`

{ lib, config, pkgs, flakeRoot, import-tree, home-manager, ... }:

let
  hostname = "traveldroid";
  modulesPath = "${flakeRoot}/generated/modules/${hostname}";
  hostModules = import-tree modulesPath;
  allModules = hostModules.imports;
in
{
  networking.hostName = hostname;
  system.stateVersion = "26.05";

  #################################
  # Locale
  #################################

  i18n = {
    defaultLocale = "nl_NL.UTF-8";
    extraLocales = [
      "nl_NL.UTF-8/UTF-8"
      "en_US.UTF-8/UTF-8"
    ];
    consoleKeyMap = "us";
  };

  time.timeZone = "Europe/Amsterdam";

  #################################
  # Imports
  #################################

  imports =
    [ ../../../generated/users/henrov.nix
      ./boot.nix
      ./hardware-configuration.nix
    ]
    ++ allModules
    ++ [ home-manager.nixosModules.home-manager ];

  #################################
  # Home Manager integration
  #################################

  home-manager.useGlobalPkgs = true;
  home-manager.useUserPackages = true;

  environment.systemPackages = [
    pkgs.dconf
  ];

  programs.dconf.enable = true;
}

generated/traveldroid/modules/apps

`generated/modules/traveldroid/apps/2_b_installed.nix`

This installs a list of apps

{ lib, config, pkgs, flakeRoot, ... }:

let
  #################################
  # FILE
  #################################
  confPath = "${flakeRoot}/generated/assets/2_b_installed.conf";
  raw = builtins.readFile confPath;
  lines = lib.splitString "\n" raw;

  #################################
  # CLEAN LINE
  #################################
  cleanLine = line:
    let
      noCR = lib.replaceStrings [ "\r" ] [ "" ] line;
      noInlineComment = lib.head (lib.splitString "#" noCR);
    in
      lib.strings.trim noInlineComment;

  #################################
  # PARSE SECTION
  #################################
  parseSection = section:
    let
      result =
        builtins.foldl'
          (acc: line:
            let
              l = lib.strings.trim line;
            in
              if l == section then
                acc // { active = true; }
              else if lib.hasPrefix "#" l then
                acc // { active = false; }
              else if acc.active then
                acc // { entries = acc.entries ++ [ l ]; }
              else
                acc
          )
          { active = false; entries = []; }
          lines;
    in
      builtins.filter (l: l != "") (map cleanLine result.entries);

  #################################
  # NIX PACKAGES
  #################################
  packageEntries = parseSection "#packages";

  resolvePkg = name:
    let
      parts = lib.splitString "." name;
      found = lib.attrByPath parts null pkgs;
    in
      if found == null then
        throw ''
          packages.nix: package not found
          Token: ${name}
          File : ${confPath}
        ''
      else
        found;

  packages = map resolvePkg packageEntries;

  #################################
  # FLATPAKS
  #################################
  flatpakEntries = parseSection "#flatpaks";

in {
  #################################
  # Allow unfree
  #################################
  nixpkgs.config.allowUnfree = true;

  #################################
  # System packages (Nix)
  #################################
  environment.systemPackages = packages;

  #################################
  # Flatpak setup
  #################################
  services.flatpak.enable = true;

  services.flatpak.remotes = [
    {
      name = "flathub";
      location = "https://flathub.org/repo/flathub.flatpakrepo";
    }
  ];

  #################################
  # Flatpak apps
  #################################
  services.flatpak.packages = flatpakEntries;
}

`generated/modules/traveldroid/apps/emacs/emacs.nix`

This installs emacs

{ config, pkgs, lib, flakeRoot, ... }:

let
  username = config.defaultUser or "henrov";

  assetPath = "${flakeRoot}/generated/.config/emacs";

  # Emacs package with Tree-sitter support
  emacsPkg = pkgs.emacs-pgtk.override { withTreeSitter = true; };

  # Extra packages for Emacs via Home Manager
  emacsExtraPackages = epkgs: [
    epkgs.manualPackages.treesit-grammars.with-all-grammars
    epkgs.nerd-icons
    epkgs.doom-modeline
    epkgs.diminish
    epkgs.eldoc
    epkgs.pulsar
    epkgs.which-key
    epkgs.expreg
    epkgs.vundo
    epkgs.puni
    epkgs.avy
    epkgs.consult
    epkgs.vertico
    epkgs.marginalia
    epkgs.crux
    epkgs.magit
    epkgs.nerd-icons-corfu
    epkgs.corfu
    epkgs.cape
    epkgs.orderless
    epkgs.yasnippet
    epkgs.yasnippet-snippets
    epkgs.rg
    epkgs.exec-path-from-shell
    epkgs.eat
    epkgs.rust-mode
    epkgs.rustic
    epkgs.nix-mode
    epkgs.hcl-mode
    epkgs.shell-pop
    epkgs.envrc
    epkgs.nixpkgs-fmt
    epkgs.f
    epkgs.gptel
    epkgs.catppuccin-theme
    epkgs.eldoc-box
    epkgs.sideline
    epkgs.sideline-flymake
    epkgs.sideline-eglot
  ];
in
{
  # System-wide installation
  environment.systemPackages = [
    emacsPkg
  ];

  # Home Manager user-specific configuration for your default user
  home-manager.users = {
    ${username} = {
      home.sessionVariables = {
        EDITOR = "emacs";
        XDG_SCREENSHOTS_DIR = "~/screenshots";
      };

      programs.emacs = {
        enable = true;
        package = emacsPkg;
        extraPackages = emacsExtraPackages;
      };

      home.file = {
        ".emacs.d/early-init.el" = {
          source = "${assetPath}/early-init.el";
          force = true;  # <-- allow overwrite
        };
        ".emacs.d/init.el" = {
          source = "${assetPath}/init.el";
          force = true;  # <-- allow overwrite
        };
      };
    };
  };
}

`generated/modules/traveldroid/apps/flameshot.nix`

This is top file of this level which contains just an import statement for all relevant files and/or the subfolder in this folder

{ pkgs, config, lib, ... }:

let
  username = config.defaultUser or "henrov";
in
{
  ############################
  # System-level packages
  ############################
  environment.systemPackages = with pkgs; [
    flameshot
  ];

  ############################
  # Home Manager user-level configuration
  ############################
  home-manager.users."${username}" = {
    home.stateVersion = "26.05";

    home.sessionVariables = {
      SCREENSHOT_TOOL = "flameshot";
      USERNAME        = username;
    };

    # Create ~/Pictures/Screenshots by touching a dummy file
    home.file."Pictures/Screenshots/.keep" = {
      text = "";   # empty file
    };
  };
}

`generated/modules/traveldroid/apps/kitty.nix`

This file sets up Kitty terminal

{ lib, pkgs, config, flakeRoot, ... }:

let
  username = config.defaultUser or "henrov";

  extraConfigFile = "${flakeRoot}/generated/.config/kitty/extra.conf";

  extraConfig =
    if builtins.pathExists extraConfigFile
    then builtins.readFile extraConfigFile
    else "";
in
{
  #################################
  # System-wide install
  #################################
  environment.systemPackages = [
    pkgs.kitty
  ];

  #################################
  # Home Manager
  #################################
  home-manager.users = {
    "${username}" = {

      programs.kitty = {
        enable = true;

        settings = {
          confirm_os_window_close    = lib.mkForce 0;
          dynamic_background_opacity = lib.mkForce true;
          enable_audio_bell          = lib.mkForce false;
          mouse_hide_wait            = lib.mkForce "-1.0";
          window_padding_width       = lib.mkForce 10;
          background_opacity         = lib.mkForce "0.5";
          background_blur            = lib.mkForce 5;
        };

        extraConfig = ''
          ${extraConfig}

          # Theme
          include themes/Catppuccin-Mocha.conf
        '';
      };
    };
  };
}

`generated/modules/traveldroid/apps/openoffice.nix`

This file sets up Kitty terminal

{ pkgs, lib, ... }:
{
  environment.systemPackages = [ pkgs.onlyoffice-desktopeditors ];

  nixpkgs.config.allowUnfreePredicate = pkg:
    builtins.elem (lib.getName pkg) [ "corefonts" ];

  fonts.packages = with pkgs; [
    corefonts
  ];

  # Automatically copy corefonts to ~/.local/share/fonts for ONLYOFFICE
  systemd.user.services.onlyoffice-fonts = {
    description = "Copy corefonts to user font directory for ONLYOFFICE";
    wantedBy = [ "default.target" ];
    serviceConfig = {
      Type = "oneshot";
      RemainAfterExit = true;
    };
    script = ''
      mkdir -p $HOME/.local/share/fonts
      cp -f ${pkgs.corefonts}/share/fonts/truetype/* $HOME/.local/share/fonts/
      chmod 644 $HOME/.local/share/fonts/*
      ${pkgs.fontconfig}/bin/fc-cache -f $HOME/.local/share/fonts
    '';
  };
}

`generated/modules/traveldroid/apps/starship.nix`

This file sets up starship prompt

{ lib, config, pkgs, flakeRoot, ... }:

let
  # Default username fallback
  username = config.defaultUser or "henrov";

  # Path to the starship config in assets
  starshipConfSrc = "${flakeRoot}/generated/.config/starship.toml";
in
{
  #################################
  # Install Starship system-wide
  #################################
  environment.systemPackages = [ pkgs.starship ];

  #################################
  # Home Manager user configuration
  #################################
  home-manager.users = {
    ${username} = {

      home.file = {
        ".config/starship.toml" = {
          text = builtins.readFile "${starshipConfSrc}";
          force = true;
        };
      };
    };
  };
}

`generated/modules/traveldroid/apps/thunar.nix`

This is top file of this level which contains just an import statement for all relevant files and/or the subfolder in this folder

{ pkgs, config, lib, ... }:

let
  # Resolve the default username from host config
  username = config.defaultUser or "henrov";
in
{
  ############################
  # System-level packages
  ############################
  environment.systemPackages = with pkgs; [
    thunar                  # main file manager
    thunar-archive-plugin    # zip, tar, rar, 7z support
    thunar-volman            # auto-mount removable drives
    gvfs                     # support for external drives and network shares
    xarchiver                # optional GUI archive manager
    tumbler                  # Showing thumbnails
    libmtp
    mtpfs
    jmtpfs
  ];

  ############################
  # Home Manager user-level configuration
  ############################
  # Direct assignment to the user avoids recursiveUpdate issues
  home-manager.users."${username}" = {
    home.stateVersion = "26.05";  # required

    home.sessionVariables = {
      FILE_MANAGER = "thunar";
      USERNAME     = username;
    };
  };
  # Enable gvfs as a service
  services.gvfs.enable = true;
}

`generated/modules/traveldroid/apps/wofi.nix`

This is the install for Wofi, the launcher

{ lib, config, pkgs, flakeRoot, ... }:

let
  username = config.defaultUser or "henrov";
  assetPath = "${flakeRoot}/generated/.config/wofi";
in
{
  environment.systemPackages = [ pkgs.wofi ];

  home-manager.users = {
    ${username} = {
      home.file = {
        ".config/wofi/config" = {
          text = builtins.readFile "${assetPath}/config";
          force = true;
        };
        ".config/wofi/style.css" = {
          text = builtins.replaceStrings ["PLACEHOLDER_USERNAME"] [username] (builtins.readFile "${assetPath}/style.css");
          force = true;
        };
      };
    };
  };
}

`generated/modules/traveldroid/apps/zenbrowser.nix`

This installs zen browser

{ config, pkgs, lib, zen-browser, ... }:

let
  # Grab the Zen Browser package for this host system
  zenBrowser = zen-browser.packages.${pkgs.stdenv.hostPlatform.system}.default;
in
{
  environment.systemPackages =  [
    zenBrowser
  ];
}

`generated/modules/traveldroid/apps/zsh.nix`

This sets up the zsh in the terminal

{ lib, config, pkgs, flakeRoot, ... }:

let
  #################################
  # User config
  #################################
  username = config.defaultUser or "henrov";
  generatedZsh = "${flakeRoot}/generated/.config/zsh/.zshrc";

  #################################
  # Alias parsing
  #################################
  aliasFile = "${flakeRoot}/generated/assets/aliases.conf";
  content = builtins.readFile aliasFile;

  lines =
    lib.filter (l: l != "")
      (map (l:
        let
          noComment = builtins.head (lib.splitString "#" l);
        in lib.trim noComment
      ) (lib.splitString "\n" content));

  parseLine = line:
    let
      parts = lib.splitString "=" line;
    in
      if lib.length parts < 2 then null else {
        name = lib.trim (lib.head parts);
        value = lib.trim (lib.concatStringsSep "=" (lib.tail parts));
      };

  parsed =
    lib.filter (x: x != null)
      (map parseLine lines);

  functions =
    lib.concatStringsSep "\n"
      (map (x: ''
        ${x.name}() {
          ${x.value} "$@"
        }
      '') parsed);

in
{
  #################################
  # Packages
  #################################
  environment.systemPackages = with pkgs; [
    zsh
    oh-my-zsh
    starship
    zsh-syntax-highlighting
  ];

  #################################
  # Zsh config location
  #################################
  environment.etc."zshenv".text = ''
    export ZDOTDIR=$HOME/.config/zsh
  '';

  #################################
  # Generated alias functions (system-wide)
  #################################
  environment.etc."profile.d/99-alias-functions.sh".text = ''
    # system-wide functions generated from aliases.conf
    ${functions}
  '';

  #################################
  # Global zshrc
  #################################
  environment.etc."zshrc".text = ''
    export ZSH=${pkgs.oh-my-zsh}/share/oh-my-zsh
    ZSH_THEME=""
    plugins=(git sudo extract colored-man-pages command-not-found history docker kubectl)

    source $ZSH/oh-my-zsh.sh

    # Init starship FIRST (prompt)
    eval "$(starship init zsh)"

    # Load alias functions
    if [ -f /etc/profile.d/99-alias-functions.sh ]; then
      source /etc/profile.d/99-alias-functions.sh
    fi

    # Load optional generated user config
    [ -f "${generatedZsh}" ] && source "${generatedZsh}"

    # Syntax highlighting MUST be last
    source ${pkgs.zsh-syntax-highlighting}/share/zsh-syntax-highlighting/zsh-syntax-highlighting.zsh
  '';

  #################################
  # Home Manager integration
  #################################
  home-manager.users.${username} = {
    programs.zsh.enable = true;
    home.file.".config/zsh/.zshrc".source = generatedZsh;
  };
}

generated/modules/traveldroid/desktop

`generated/modules/traveldroid/desktop/fonts.nix`

This file installs and configures fonts

{ lib, pkgs, config, ... }:

{
    fonts.packages = with pkgs; [
      nerd-fonts.iosevka
      nerd-fonts.fira-code
      nerd-fonts.jetbrains-mono
    ];
}

`generated/modules/traveldroid/desktop/gtk.nix`

Setting up GTK

{ pkgs, config, lib, ... }:

let
  username = config.defaultUser or "henrov";
in
{
  environment.systemPackages = with pkgs; [
    gtk3
    gtk4
  ];

  home-manager.users."${username}" = {
    gtk = {
      enable = true;
    };
  };
}

`generated/modules/traveldroid/desktop/hyprland.nix`

Setting up Hyprland

{ lib, config, pkgs, flakeRoot, home-manager, inputs, ... }:

let
  username = config.defaultUser or "henrov";
  assetPath = "${flakeRoot}/generated/.config/hypr";

  hyprlandPkg =
    pkgs.hyprland or
    pkgs.hyprland-git or
    inputs.hyprland.packages.${pkgs.system}.default;

in
{
  # Install Hyprland systemwide
  environment.systemPackages = [ hyprlandPkg ];

  # Home Manager user configuration
  home-manager.users = {
    ${username} = {
      home.file = {
        ".config/hypr/animations.conf"     = { source = "${assetPath}/animations.conf"; force = true; };
        ".config/hypr/behaviour.conf"     = { source = "${assetPath}/behaviour.conf"; force = true; };
        ".config/hypr/bindings.conf"      = { source = "${assetPath}/bindings.conf"; force = true; };
        ".config/hypr/exec-once.conf"     = { source = "${assetPath}/exec-once.conf"; force = true; };
        ".config/hypr/hypridle.conf"      = { source = "${assetPath}/hypridle.conf";  force = true; };
        ".config/hypr/hyprland.conf"      = { source = "${assetPath}/hyprland.conf"; force = true; };
        ".config/hypr/hyprlock.conf"      = { source = "${assetPath}/hyprlock.conf";  force = true; };
        ".config/hypr/layer-rules.conf"   = { source = "${assetPath}/layer-rules.conf"; force = true; };
        ".config/hypr/layout.conf"        = { source = "${assetPath}/layout.conf"; force = true; };
        ".config/hypr/monitor-rules.conf" = { source = "${assetPath}/monitor-rules.conf"; force = true; };
        ".config/hypr/theming.conf"        = { source = "${assetPath}/theming.conf"; force = true; };
        ".config/hypr/window-rules.conf"  = { source = "${assetPath}/window-rules.conf"; force = true; };
        ".config/hypr/workspace-rules.conf" = { source = "${assetPath}/workspace-rules.conf"; force = true; };
      };
    };
  };
}

`generated/modules/traveldroid/desktop/stylix.nix`

{ lib, config, pkgs, flakeRoot, stylix, ... }:

let
  username   = config.defaultUser or "henrov";
  moduleName = "stylix";

  assetPath  = "${flakeRoot}/generated/.config/${moduleName}";

  stylixConfFile = "${assetPath}/stylix.conf";
  stylixConf =
    if builtins.pathExists stylixConfFile
    then builtins.readFile stylixConfFile
    else "";

  cursorName = "phinger-cursors-light";
  cursorSize = 24;
in
{
  #################################
  # Enable Stylix module
  #################################
  imports = [
    stylix.nixosModules.stylix
  ];

  #################################
  # System packages
  #################################
  environment.systemPackages = [
    pkgs.feh
    pkgs.st
  ];

  #################################
  # Stylix system config
  #################################
  stylix = {
    enable = true;

    base16Scheme = "${flakeRoot}/assets/traveldroid/theming/stylix/catppuccin-mocha.yaml";
    polarity = "dark";

    targets = {
      gtk.enable = true;
      qt.enable  = true;
    };

    cursor = {
      name    = cursorName;
      package = pkgs.phinger-cursors;
      size    = cursorSize;
    };
  };

  #################################
  # Home Manager
  #################################
  home-manager.users = {
    "${username}" = {

      #################################
      # ONLY custom file (safe)
      #################################
      home.file.".config/stylix/stylix.conf" = {
        text  = stylixConf;
        force = true;
      };

      #################################
      # Environment variables
      #################################
      home.sessionVariables = {
        STYLIX_CONF      = "$HOME/.config/stylix/stylix.conf";
        XCURSOR_THEME    = cursorName;
        XCURSOR_SIZE     = toString cursorSize;
        HYPRCURSOR_THEME = cursorName;
        HYPRCURSOR_SIZE  = toString cursorSize;
      };
    };
  };
}

`generated/modules/traveldroid/desktop/wallpaper.nix`

Setting up wallpaper engine + wallpaper gui

{ lib, config, pkgs, flakeRoot, ... }:

let
  username     = config.defaultUser or "henrov";
  homeDir      = "/home/${username}";
  wallpaperSrc = "${flakeRoot}/assets/traveldroid/Wallpapers";
  wallpaperDst = "${homeDir}/Wallpapers";
  randoScript  = "${homeDir}/Wallpapers/scripts/randomizeWallpapers.sh";
in
{
  # Make bash available
  environment.systemPackages = [ pkgs.bash pkgs.rsync pkgs.jq pkgs.awww pkgs.waypaper pkgs.socat ];

  # Create the copy script using Home Manager, following Waybar style
  home-manager.users = {
    ${username} = {
      home.file = {
        "copy-wallpapers.sh" = {
          text = ''
            #!/run/current-system/sw/bin/bash
            set -euo pipefail
            echo "Running as $(whoami)"
            echo "Copying wallpapers from ${wallpaperSrc} to ${wallpaperDst} ..."
            if [ ! -d "${wallpaperSrc}" ]; then
              echo "ERROR: ${wallpaperSrc} does not exist"
              exit 1
            fi
            mkdir -p "${wallpaperDst}"
            # Simple copy, overwrite everything
            cp -r "${wallpaperSrc}/." "${wallpaperDst}/"
            # Fix permissions
            chmod -R u+rwx "${wallpaperDst}"
            echo "Done copying wallpapers."
          '';
          executable = true;
          force = true;
        };
      };
    };
  };

  # User service to run the script that copies the Wallpaperstuff
  systemd.user.services.copyWallpapers = {
    description = "Copy wallpapers from repo to ~/Wallpapers";
    serviceConfig = {
      Type      = "oneshot";
      ExecStart = "${homeDir}/copy-wallpapers.sh";
      Restart   = "no";
      WorkingDirectory = homeDir;
    };
    wantedBy = [ "default.target" ];
  };

  # User service to randomize wallpapers
  systemd.user.services.randomizeWallpapers = {
    description = "Randomize wallpapers in ~/Wallpapers/pictures";
    serviceConfig = {
      Type      = "oneshot";
      ExecStart = "${randoScript}";
      Restart   = "no";
      WorkingDirectory = homeDir;
    };
    wantedBy = [ "default.target" ];
  };

  ############################
  # Random background per workspace at logon
  ############################

  systemd.user.services.workspaceWallpapers = {
    description = "Dynamic wallpapers per workspace for Hyprland";
    after = [ "graphical-session.target" ];
    wants = [ "graphical-session.target" ];

    serviceConfig = {
      Type = "simple";
      ExecStart = "${homeDir}/Wallpapers/scripts/workspace-wallpapers.sh";
      Restart = "on-failure";
      RestartSec = 5;
      WorkingDirectory = homeDir;
      Environment = [
          "HYPRLAND_INSTANCE_SIGNATURE=${builtins.getEnv "HYPRLAND_INSTANCE_SIGNATURE"}"
        "WAYLAND_DISPLAY=wayland-1"
        "PATH=/run/current-system/sw/bin:/usr/bin:/bin"
      ];
    };

    wantedBy = [ "default.target" ];
  };
}

`generated/modules/traveldroid/desktop/waybar.nix`

This file installs and configures waybar

{ lib, config, pkgs, flakeRoot, ... }:
let
  # Use the config option defaultUser directly, fallback to "henrov"
  username = config.defaultUser or "henrov";
  basePath = "${flakeRoot}/generated/.config";
  assetPath = "${flakeRoot}/generated/.config/waybar";
in
{
  # Install Waybar system-wide
  environment.systemPackages = [ pkgs.waybar ];

  home-manager.users = {
      ${username} = {
        home.file = {
          ".config/waybar/config" = {
            text = builtins.readFile "${assetPath}/config";
            force = true;
          };
          ".config/waybar/style-dark.css" = {
            text = builtins.replaceStrings ["henrov"] [username] (builtins.readFile "${assetPath}/style-dark.css");
            force = true;
          };
          ".config/scripts/bluetooth-status.sh" = {
            text = builtins.readFile "${basePath}/scripts/bluetooth-status.sh";
            force = true;
            executable = true;
          };
          ".config/scripts/hypr-workspaces.sh" = {
            text = builtins.readFile "${basePath}/scripts/hypr-workspaces.sh";
            force = true;
            executable = true;
          };
          ".config/scripts/hypr-workspacesmenu.sh" = {
            text = builtins.readFile "${basePath}/scripts/hypr-workspacesmenu.sh";
            force = true;
            executable = true;
          };
        };
      };
    };

  # Systemd user service for Waybar
  systemd.user.services.waybar = {
    description = "Waybar for Hyprland";
    after = [ "graphical-session.target" ];

    serviceConfig = {
      ExecStart = "${pkgs.waybar}/bin/waybar";
      Restart = "always";
      Environment = ''
        WAYLAND_DISPLAY=${config.environment.sessionVariables.WAYLAND_DISPLAY or "wayland-0"}
        XDG_CURRENT_DESKTOP=Hyprland
      '';
    };

    wantedBy = [ "default.target" ];
  };
}

`generated/modules/traveldroid/desktop/wayland.nix`

{ lib, config, pkgs, ... }:

{
  #################################
  # Core Wayland packages
  #################################
  environment.systemPackages = with pkgs; [
    wayland
    wl-clipboard      # optional but commonly used for copy/paste
  ];

  #################################
  # enable graphics stack
  #################################
  hardware.graphics.enable = true;

  #################################
  # Optional session variables for Wayland
  #################################
  environment.sessionVariables = {
    # Forces some apps to use Wayland
    NIXOS_OZONE_WL = "1";
  };
}

`generated/modules/traveldroid/desktop/xdg.nix`

This sets the XDG implementation

{ lib, config, pkgs, flakeRoot, ... }:

let
  # Use the config option defaultUser directly, fallback to "henrov"
  username = config.defaultUser or "henrov";

  # Portal backends
  basePortal = pkgs.xdg-desktop-portal-gtk;    # full portal implementation
  hyprlandPortal = pkgs.xdg-desktop-portal-hyprland;  # Hyprland screencast
in
{
  #################################
  # Enable XDG desktop portals system-wide
  #################################
  xdg.portal.enable = true;

  # Base + Hyprland portals
  xdg.portal.extraPortals = [ basePortal hyprlandPortal ];

  # Map screencast interface explicitly to Hyprland
  xdg.portal.config = {
    "org.freedesktop.impl.portal.Screencast".backend = "hyprland";
  };

  #################################
  # Install portal packages system-wide
  #################################
  environment.systemPackages = [
    basePortal
    hyprlandPortal
  ];

  #################################
  # Home Manager user configuration
  #################################
  home-manager.users = {
    ${username} = {
      home.packages = [
        basePortal
        hyprlandPortal
      ];
    };
  };
}

generated/modules/traveldroid/system

`generated/modules/traveldroid/system/audio.nix`

{ lib, config, pkgs, ... }:

{
  ############################
  # Audio system
  ############################
  environment.systemPackages = with pkgs; [
    pulseaudio       # PulseAudio daemon
    pavucontrol      # GUI mixer
    pamixer          # CLI mixer
    playerctl        # Player controls
  ];
}

`generated/modules/traveldroid/system/avahi.nix`

Avahi helps discovering services

{ ... }:
{
  services.avahi = {
    enable = true;
    nssmdns4 = true;
    publish = {
      enable = true;
      addresses = true;
    };
  };
}

`generated/modules/traveldroid/system/bluetooth.nix`

Installing Bluetooth services and supporting aps

{ lib, config, pkgs, home-manager, ... }:

let
  username = config.defaultUser or "henrov";
in
{


  ############################
  # Bluetooth daemon
  ############################
  hardware.bluetooth = {
    enable      = true;
    powerOnBoot = true;
    package     = pkgs.bluez;
      };
  environment.systemPackages = with pkgs; [ blueman ];
}

`generated/modules/traveldroid/system/copy_scripts.nix`

This copies any scripts from generated.config/scripts to ~/.config/scripts and makes any .sh files executable.

{ lib, config, pkgs, flakeRoot, ... }:
let
  username = config.defaultUser or "henrov";
  configPath = flakeRoot + "/generated/.config/scripts";
  allFiles = lib.filesystem.listFilesRecursive configPath;

  toRelative = file:
    let
      base = toString flakeRoot + "/generated/";
      relative = lib.removePrefix base (toString file);
    in
      builtins.unsafeDiscardStringContext relative;

  isShellScript = file:
    lib.hasSuffix ".sh" (toString file);

  toFileEntry = file: {
    name = toRelative file;
    value = {
      source = file;
      executable = isShellScript file;
      force = true;
    };
  };
in
{
  home-manager.users = {
    ${username} = {
      home.file = builtins.listToAttrs (map toFileEntry allFiles);
    };
  };
}

`generated/modules/traveldroid/system/dbus.nix`

This sets the dbus implementation

{ config, pkgs, ... }:

{
  # Enable classic D-Bus service
  services.dbus.enable = true;

  # Use default dbus package (classic D-Bus)
  services.dbus.dbusPackage = pkgs.dbus;

  # Include some essential system packages so shell and tools exist
  environment.systemPackages = with pkgs; [
    bashInteractive
    coreutils
  ];

  # Do not attempt to wrap dbus-daemon-launch-helper manually
  # No extra security.wrappers needed
}

`generated/modules/traveldroid/system/firewall.nix`

This sets the firewall.

{ pkgs, ... }:

{
  # Use nftables as the firewall backend
  networking.nftables.enable = true;

  networking.firewall = {
    enable = true;

    filterForward = false;  # don't filter forwarded traffic
    # outbound is allowed by default UNLESS you've set:

    # LAN-only ports — Wi-Fi interface
    interfaces."wlan0" = {
      allowedTCPPorts = [
        22     # SSH
        80     # allow HTTP globally for outbound
        443    # allow HTTPS globally for outbound
        631    # CUPS / IPP network printing
        9100   # AppSocket/JetDirect printing
        6566   # SANE network scanner
        57621  # Spotify Connect
        57622  # Spotify local file sync
      ];
      allowedTCPPortRanges = [
        { from = 1714; to = 1764; }  # KDE Connect
      ];
      allowedUDPPorts = [
        5353   # mDNS / Avahi (printer + device discovery)
        631    # CUPS / IPP
        67     # DHCP
        123    # NTP time sync
        1900   # UPnP device discovery
        57621  # Spotify Connect
      ];
      allowedUDPPortRanges = [
        { from = 1714; to = 1764; }  # KDE Connect
      ];
    };

    # LAN-only ports — ethernet (ready for when you plug in)
    interfaces."enp0s31f6" = {
      allowedTCPPorts = [
        631    # CUPS / IPP network printing
        9100   # AppSocket/JetDirect printing
        6566   # SANE network scanner
        57621  # Spotify Connect
        57622  # Spotify local file sync
      ];
      allowedTCPPortRanges = [
        { from = 1714; to = 1764; }  # KDE Connect
      ];
      allowedUDPPorts = [
        5353   # mDNS / Avahi (printer + device discovery)
        631    # CUPS / IPP
        67     # DHCP
        123    # NTP time sync
        1900   # UPnP device discovery
        57621  # Spotify Connect
      ];
      allowedUDPPortRanges = [
        { from = 1714; to = 1764; }  # KDE Connect
      ];
    };
  };

  # CLI tool for temporary rule changes without rebuilding
  # Usage: sudo nixos-firewall-tool open tcp 8080
  environment.systemPackages = with pkgs; [
    nixos-firewall-tool
  ];
}

`generated/modules/traveldroid/system/hypridle.nix`

This installs hypridle

{ lib, config, pkgs, flakeRoot, ... }:

let
  username = config.defaultUser or "henrov";
  basePath = "${flakeRoot}/generated/.config";
  assetPath = "${flakeRoot}/generated/.config/hypr";
in
{
  #################################
  # Install hypridle system-wide
  #################################
  environment.systemPackages = [ pkgs.hypridle ];

  #################################
  # Deploy config
  #################################
  home-manager.users = {
    ${username} = {
      home.file = {
        ".config/hypr/hypridle.conf" = {
          text = builtins.readFile "${assetPath}/hypridle.conf";
          force = true;
        };
      };
    };
  };

  #################################
  # Systemd user service
  #################################
  systemd.user.services.hypridle = {
    description = "Hypridle (Hyprland idle daemon)";
    after = [ "graphical-session.target" ];

    serviceConfig = {
      ExecStart = "${pkgs.hypridle}/bin/hypridle";
      Restart = "always";
      Environment = ''
        WAYLAND_DISPLAY=${config.environment.sessionVariables.WAYLAND_DISPLAY or "wayland-0"}
        XDG_CURRENT_DESKTOP=Hyprland
      '';
    };
    wantedBy = [ "default.target" ];
  };
}

`generated/modules/traveldroid/system/hyprlock.nix`

This installs hyprlock

{ lib, config, pkgs, flakeRoot, ... }:

let
  username = config.defaultUser or "henrov";
  basePath = "${flakeRoot}/generated/.config";
  assetPath = "${flakeRoot}/generated/.config/hypr";
in
{
  #################################
  # Install hyprlock system-wide
  #################################
  environment.systemPackages = [
    pkgs.hyprlock
  ];

  #################################
  # Deploy configuration file
  #################################
  home-manager.users = {
    ${username} = {
      home.file = {
        ".config/hypr/hyprlock.conf" = {
          text = builtins.readFile "${assetPath}/hyprlock.conf";
          force = true;
        };
      };
    };
  };

  #################################
  # Optional: helper systemd user service (manual start use)
  #################################
  systemd.user.services.hyprlock = {
    description = "Hyprlock (manual lock session)";
    after = [ "graphical-session.target" ];

    serviceConfig = {
      ExecStart = "${pkgs.hyprlock}/bin/hyprlock";
      Restart = "no";
      Environment = ''
        WAYLAND_DISPLAY=${config.environment.sessionVariables.WAYLAND_DISPLAY or "wayland-0"}
        XDG_CURRENT_DESKTOP=Hyprland
      '';
    };

    wantedBy = [ ];
  };
}

`generated/modules/traveldroid/system/gnome-keyring.nix`

This sets the dbus implementation

{ config, pkgs, ... }:

{
  ##################################################
  # Core services
  ##################################################

  # Enable GNOME Keyring
  services.gnome.gnome-keyring.enable = true;

  ##################################################
  # PAM (auto unlock keyring on login)
  ##################################################

  security.pam.services = {
    login.enableGnomeKeyring = true;
    greetd.enableGnomeKeyring = true;
    sddm.enableGnomeKeyring = true;
    gdm.enableGnomeKeyring = true;
  };

  ##################################################
  # Environment packages
  ##################################################

  environment.systemPackages = with pkgs; [
    polkit_gnome
    seahorse
    libsecret
  ];

  ##################################################
  # Security / Polkit
  ##################################################

  security.polkit.enable = true;


}

`generated/modules/traveldroid/system/login-tuigreet.nix`

This sets up tuigreeter which is not fancy but imo fits the aesthetic I am aiming for

{ config, pkgs, lib, ... }:

let
  tuigreetBin = "${pkgs.tuigreet}/bin/tuigreet";
  sessionsDir = "${pkgs.hyprland}/share/wayland-sessions";
in
{
  #################################
  # Greetd (tuigreet)
  #################################

  services.greetd = {
    enable = true;

    settings = {
      default_session = {
        command = ''
          ${tuigreetBin} \
            --time \
            --remember \
            --remember-session \
            --sessions ${sessionsDir} \
            --cmd "start-hyprland"
        '';
        user = "greeter";
      };
    };
  };

  #################################
  # Fix TTY / boot noise issues
  #################################

  systemd.services.greetd.serviceConfig = {
    Type = "idle";
    StandardInput = "tty";
    StandardOutput = "tty";
    StandardError = "journal";

    # Prevent boot log spam on tty
    TTYReset = true;
    TTYVHangup = true;
    TTYVTDisallocate = true;
  };
}

`generated/modules/traveldroid/system/networking.nix`

This sets the networking.

{ lib, config, pkgs, ... }:

{
  #################################
  # Networking core
  #################################
  networking = {
    # Let DHCP be default unless overridden elsewhere
    useDHCP = lib.mkDefault true;

    #################################
    # NetworkManager (primary stack)
    #################################
    networkmanager = {
      enable = true;
      # Use iwd backend for WiFi
      wifi.backend = "iwd";
    };

    #################################
    # iwd (WiFi daemon)
    #################################
    wireless.iwd = {
      enable = true;
      # Allow user control via NM / CLI
      settings.General.EnableNetworkConfiguration = true;
    };
  };

  #################################
  # System packages
  #################################
  environment.systemPackages = [
    pkgs.networkmanager
    pkgs.linux-firmware
    pkgs.networkmanagerapplet
    pkgs.networkmanager_dmenu
    pkgs.iwgtk
  ];
}

`generated/modules/traveldroid/system/nix.nix`

{ lib, config, ... }:

{
    nix.settings = {
      experimental-features = [ "nix-command" "flakes" ];
      download-buffer-size = 536870912; # 512 MB
      cores = 2;
      max-jobs = 1;
    };
}

`generated/modules/traveldroid/system/printing.nix`

This sets the dbus implementation

{ lib, config, pkgs, ... }:

{
  ############################
  # Printing system
  ############################
  services.printing.enable = true;          # enable CUPS printing service

  ############################
  # System packages for GUI management
  ############################
  environment.systemPackages = with pkgs; [
    system-config-printer    # GUI to manage printers
  ];
}

`generated/modules/traveldroid/system/quickshell.nix`

This sets the dbus implementation

{ pkgs, lib, config, flakeRoot, ... }:
let
  username = config.defaultUser or "henrov";
  quickshellPath = flakeRoot + "/generated/.config/quickshell";
  allFiles = lib.filesystem.listFilesRecursive quickshellPath;

  toRelative = file:
    let
      base = toString flakeRoot + "/generated/";
      relative = lib.removePrefix base (toString file);
    in
      builtins.unsafeDiscardStringContext relative;

  toFileEntry = file: {
    name = toRelative file;
    value = {
      source = file;
      force = true;
    };
  };
in
{
  environment.systemPackages = with pkgs; [
    quickshell
    qt6.qtdeclarative
    qt6.qttools
    qt6.qtsvg
    qt6.qtimageformats
    qt6.qtmultimedia
    qt6.qt5compat
  ];

  qt = {
    enable = true;
    platformTheme = "qt5ct";
  };

  home-manager.users = {
    ${username} = {
      home.file = builtins.listToAttrs (map toFileEntry allFiles);
    };
  };
}

generated/users

`generated/users/`

This is the default user, just search and replace henrov another name if you want to change

{ lib, config, pkgs, ... }:

let
  username = "henrov";
in
{
  #################################
  # NixOS system user
  #################################
  users.users.${username} = {
    isNormalUser = true;
    home = "/home/${username}";
    hashedPassword = "$6$S7iShgBxB.77CwmP$i0njK.2r3OL5UEvgZbmwZ0rnpZ4QyJcv8p9uCmJ4AiVPSMXkQkIwMLzyAOnJ0q8.tPLIp/7EquEIZeK8qbmgw/";
    extraGroups = [ "wheel" "networkmanager" "bluetooth" ];
    ignoreShellProgramCheck = true;  # <-- avoids the assertion
    shell = pkgs.zsh;
  };

  #################################
  # Home Manager user definition
  #################################
  home-manager.users = {
    ${username} = {
      home.username      = username;
      home.homeDirectory = "/home/${username}";
      home.stateVersion  = "26.05";

      programs.zsh.enable = true;

      home.packages = [
        # add packages here
      ];

      # Activation to ensure the directory is writable
      home.activation.fixStylixPermissions = ''
        mkdir -p $HOME/.config
        chmod -R u+rwx $HOME/.config
      '';

      # Locale and timezone settings
      home.sessionVariables = {
        LANG   = "nl_NL.UTF-8";
        LC_ALL = "nl_NL.UTF-8";
        TZ     = "Europe/Amsterdam";
      };
    };
  };
}

These are all the prepared config files

`generated/.config/emacs/early-init.el`

This contaions emacs

;;; package --- early init -*- lexical-binding: t -*-
 ;;; Commentary:
 ;;; Prevents white flash and better Emacs defaults
 ;;; Code:
 (set-language-environment "UTF-8")
 (setq-default
default-frame-alist
'((background-color . "#1e1e2e")
  (bottom-divider-width . 1)    ; Thin horizontal window divider
  (foreground-color . "#bac2de")    ; Default foreground color
  (fullscreen . maximized)      ; Maximize the window by default
  (horizontal-scroll-bars . nil)    ; No horizontal scroll-bars
  (left-fringe . 8)       ; Thin left fringe
  (menu-bar-lines . 0)      ; No menu bar
  (right-divider-width . 1)     ; Thin vertical window divider
  (right-fringe . 8)        ; Thin right fringe
  (tool-bar-lines . 0)      ; No tool bar
  (undecorated . t)       ; Remove extraneous X decorations
  (vertical-scroll-bars . nil))   ; No vertical scroll-bars
user-full-name "Henrov henrov"      ; ME!
;; memory configuration
;; Higher garbage collection threshold, prevents frequent gc locks, reset later
gc-cons-threshold most-positive-fixnum
;; Ignore warnings for (obsolete) elisp compilations
byte-compile-warnings '(not obsolete)
;; And other log types completely
warning-suppress-log-types '((comp) (bytecomp))
;; Large files are okay in the new millenium.
large-file-warning-threshold 100000000
;; dont show garbage collection messages at startup, will reset later
garbage-collection-messages nil
;; native compilation
package-native-compile t
native-comp-warning-on-missing-source nil
native-comp-async-report-warnings-errors 'silent
;; Read more based on system pipe capacity
read-process-output-max (max (* 10240 10240) read-process-output-max)
;; scroll configuration
scroll-margin 0           ; Lets scroll to the end of the margin
scroll-conservatively 100000        ; Never recenter the window
scroll-preserve-screen-position 1     ; Scrolling back and forth
;; frame config
;; Improve emacs startup time by not resizing to adjust for custom settings
frame-inhibit-implied-resize t
;; Dont resize based on character height / width but to exact pixels
frame-resize-pixelwise t
;; backups & files
backup-directory-alist '(("." . "~/.backups/")) ; Don't clutter
backup-by-copying t           ; Don't clobber symlinks
create-lockfiles nil          ; Don't have temp files
delete-old-versions t         ; Cleanup automatically
kept-new-versions 6           ; Update every few times
kept-old-versions 2           ; And cleanup even more
version-control t           ; Version them backups
delete-by-moving-to-trash t       ; Dont delete, send to trash instead
;; startup
inhibit-startup-screen t        ; I have already done the tutorial. Twice
inhibit-startup-message t         ; I know I am ready
inhibit-startup-echo-area-message t     ; Yep, still know it
initial-scratch-message nil       ; I know it is the scratch buffer!
initial-buffer-choice nil
inhibit-startup-buffer-menu t
inhibit-x-resources t
initial-major-mode 'fundamental-mode
pgtk-wait-for-event-timeout 0.001     ; faster child frames
ad-redefinition-action 'accept      ; dont care about legacy things being redefined
inhibit-compacting-font-caches t
;; tabs
tab-width 4             ; Always tab 4 spaces.
indent-tabs-mode nil          ; Never use actual tabs.
;; rendering
cursor-in-non-selected-windows nil      ; dont render cursors other windows
;; packages
use-package-always-defer t
load-prefer-newer t
default-input-method nil
use-dialog-box nil
use-file-dialog nil
use-package-expand-minimally t
package-enable-at-startup nil
use-package-enable-imenu-support t
auto-mode-case-fold nil  ; No second pass of case-insensitive search over auto-mode-alist.
package-archives '(("melpa"    . "https://melpa.org/packages/")
        ("gnu"    . "https://elpa.gnu.org/packages/")
        ("nongnu"   . "https://elpa.nongnu.org/nongnu/")
        ("melpa-stable" . "https://stable.melpa.org/packages/"))
package-archive-priorities '(("gnu"  . 99)
            ("nongnu" . 80)
            ("melpa"  . 70)
            ("melpa-stable" . 50))
)
;;; early-init.el ends here