{ config, pkgs, lib, inputs, ... }:

let
  # Gebruik een relatief pad, geen flakeRoot
  packagesConfPath = ./assets/system/apps/packages.conf;

  raw = builtins.readFile packagesConfPath;
  rawLines = lib.splitString "\n" raw;

  _guard = assert !(builtins.stringLength raw > 1 &&
                    builtins.length rawLines == builtins.stringLength raw); true;

  cleanLine = line:
    let
      noCR = lib.replaceStrings [ "\r" ] [ "" ] line;
      noComment = lib.head (lib.splitString "#" noCR);
    in
      lib.strings.trim noComment;

  entries = builtins.filter (l: l != "") (map cleanLine rawLines);

  resolvePkg = name:
    let
      parts = lib.splitString "." name;
      found = lib.attrByPath parts null pkgs;
    in
      if found == null then
        throw ''
          packages.nix: package not found in pkgs
          Token    : ${builtins.toJSON name}
          packages.conf   : ${toString packagesConfPath}
          Hint     : check the attribute name on search.nixos.org/packages
        ''
      else
        found;

  packages = builtins.seq _guard (map resolvePkg entries);

in
{
  environment.systemPackages = packages ++ [ zenBrowser ];
}